{
  description = "ars service";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    flake-utils.url = "github:numtide/flake-utils";
    rust-overlay = {
      url = "github:oxalica/rust-overlay";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
      };
    };
    crane = {
      url = "github:ipetkov/crane";
      inputs = {
        nixpkgs.follows = "nixpkgs";
        flake-utils.follows = "flake-utils";
        rust-overlay.follows = "rust-overlay";
      };
    };
  };

  outputs = { self, nixpkgs, flake-utils, rust-overlay, crane}: let
    forAllSystems = function:
      nixpkgs.lib.genAttrs [
        "x86_64-linux"
        "aarch64-linux"
      ] (system: function system nixpkgs.legacyPackages.${system});
  in rec {
    packages = forAllSystems(system: syspkgs: let
        pkgs = import nixpkgs {
          inherit system;
          overlays = [ (import rust-overlay) ];
        };
        rustToolchain = pkgs.rust-bin.stable.latest.default;

        craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;
        src = pkgs.lib.cleanSourceWith {
          src = craneLib.path ./.;
          filter = path: type:
            (pkgs.lib.hasSuffix "\.md" path) ||
            (pkgs.lib.hasSuffix "\.stpl" path) ||
            (pkgs.lib.hasInfix "static" path) ||
            (craneLib.filterCargoSources path type)
          ;
        };

        nativeBuildInputs = with pkgs; [ rustToolchain pkg-config ];
        buildInputs = with pkgs; [ ];

        commonArgs = {
          inherit src buildInputs nativeBuildInputs;
        };
        cargoArtifacts = craneLib.buildDepsOnly commonArgs;

        ars = craneLib.buildPackage (commonArgs // {
          inherit cargoArtifacts;
          pname = "ars";
          installPhaseCommand = ''
            mkdir -p $out/bin
            cp target/release/ars $out/bin/ars
            cp -r static $out/static
          '';
        });

    in {
      inherit ars;
      default = ars;
    });
    devShells = forAllSystems(system: pkgs: pkgs.mkShell {
      inputsFrom = [ packages.${system}.ars ];
    });
    hydraJobs."ars" = forAllSystems(system: pkgs: packages.${system}.ars);
  };
}